open/close all/selected groups

why not assign "open group" a keyboard shortcut let say :

---> costumize -->keyboard --> category [Groups] Group Open --> Assign keyboard to Group Open ex : Ctrl+Shift+R

let select closed group [ multiple selection is OK ] and then press Ctrl+Shift+R...closed group should be opened.....you know what you do next....I guess

hi fajar,

thank you for your feedback but honestly i do not really understand your question. do you mind try to explain it again?

TIA

I guess this works (I Dont have max here right now, so i have not tested)

for o in group_arr where not o.isHidden do

Integrated in Open All Groups:

macroScript OPEN_ALL_GROUPS Category:"Custom" toolTip:"open all groups" (
	fn openGroupsAll objs toggle= (
		group_arr = for o in objs where isValidNode o AND isGroupHead o collect o
	 
		with redraw off (
			for o in group_arr where not o.isHidden do (
				setGroupOpen o toggle
				-- ungroup o
			) -- end for
		)-- end redraw
	) -- end fn

	openGroupsAll objects true
)

not sure I did what you said correctly as it dont seem to work.

But anyway waiting for the script creator to reply!

thx!

"Right now, it opens the groups of objects that are on hidden layer."

i think it is a question of personal workflow if
a) all groups
b) selected groups
c) all but not hidden groups
should be implemented.

For me i only use open and close ALL groups. As soon i am done editing my desired object i just close all groups.

But i will extend the version with the requested feature open/close all and selected but not hidden groups.

Will post updated version as soon as possible.

Thx sir!

It's definitely a question of workflow, but I think that if it's made so that whats hidden isn't affected is just more clean and powerful and thus can adapt to any workflow.

More logical also no? But yeah why code something you don't use, I understand. :)

But it's just that small little detail thats missing making this script complete I think. :)

Anyway! Thx for considering updating it man, appreciate and thx for your work!

many thanks for your feedback :)
i just uploaded the new version (v 0.2)

Hi le1setreter,

You snippets are great :)

Here is my approach to do Open and close groups (based on your first code):

-----------------------------------------------------------------
-- Open/Close All Groups (Not hidden Groups)
-----------------------------------------------------------------
try (destroyDialog ::rol_OpenCloseGroups) catch()
 
rollout rol_OpenCloseGroups "Open/Close Groups"
(
    checkbutton ckb_OpenClose "OPEN GROUP" height:35 width:140 highlightColor:[0,80,255] tooltip:"OPEN / CLOSE GROUPS"
     
     
    fn openGroupsAll objs toggle=
    (
        group_arr = for o in objs where isValidNode o AND isGroupHead o collect o
  
        with redraw off
        (
            for o in group_arr where not o.isHidden do
            (
                setGroupOpen o toggle
            ) 
        )
    )
 
    on ckb_OpenClose changed state do
    (
        if not state then 
        (
            openGroupsAll objects false
            ckb_OpenClose.text = "OPEN GROUP"
        )
        else
        (
            openGroupsAll objects true
            ckb_OpenClose.text = "CLOSE GROUP"
        )
    )
)
         
createDialog rol_OpenCloseGroups width:150 height:45

try (destroyDialog ::rol_OpenCloseGroups) catch()
rollout rol_OpenCloseGroups "Open/Close Groups"
(
fn groupFIlter grp = isGroupHead grp and not grp.isHidden
mapped fn openGroups arr toggle: = if groupFIlter arr do setGroupOpen arr toggle
checkbutton ckb_OpenClose "OPEN GROUP" height:35 width:140 highlightColor:[0,80,255] tooltip:"OPEN / CLOSE GROUPS"
on ckb_OpenClose changed state do
(
openGroups (helpers as array) toggle:state
ckb_OpenClose.text = (if state then "CLOSE" else "OPEN") + " GROUP"
)
)
createdialog rol_OpenCloseGroups

Hehe :)

Thank you barigazy :)

My pleasure :)

nicely done :)

Hi le1setreter,

thx for having considered the comments and do the update so fast!

Good work!

Hi,

first of all great job this script is really handy for us here.

One thing though, would it be possible to make it so that it don't open the groups that are hidden?

Right now, it opens the groups of objects that are on hidden layer.

Let me know!

Thx!

Cool idea. Recently I've been thinking about *Group Manager* tool similar to Layer Manager. Maybe someone can write this soon.
Anyway, keep up the good work.
Cheers!