Flip Faces on Selected objects?

By net_ralf · 2010-03-10

Description

I am looking for a script that flips all the faces of multiple selected objects. I had to import a cad file and there are gazillions of small faces fliped. any idea? The script should maybe automated apply the normal modifier and then convert it to mesh.

Thanx in advance

Ralf

Comments (3)

Budi G · 2010-10-24

An alternative way to use a script without normals modifier, Please check the link below :
http://www.scriptspot.com/3ds-max/scripts/unify-flip-normal-polygons

Graph · 2010-03-13

have phun :P


(
	-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- 
	-- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- 
	--      --      --      --      --      --      --      --      --      
	---  brought --- to --- you --- by --- IN-Tools.biz --
	--      --      --      --      --      --      --      --      --      
	-- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- - -- 
	-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- 
	
	rollout flipFlop "FlipFlop"
	(
		group ""
		(
			checkBox unify "Unify" across:2
			checkBox flip "Flip" checked:true
			
			radiobuttons processType "Processing" labels:#("Single", "Group") align:#left columns:3
			
			radiobuttons meshType "Convert To" labels:#("Poly", "Mesh", "None") default:3 align:#left columns:3
		)
		
		button Process "Process" width:(flipFlop.width-10) height:30 toolTip:"Go Panters!"
		
		on process pressed do
		(
			with undo on
			(
				local sel = selection as array
				local normalMod = normalModifier()
				normalMod.unify = unify.checked
				normalMod.flip = flip.checked
				
				if processType.state == 1 then
				(
					for obj in sel do
					(
						addModifier obj normalMod
						
						case meshType.state  of
						(
							1 : (
								convertToPoly obj
							)
							2 : (
								convertToMesh obj
							)
							3 : ()
						)
						
					)--END obj loop
				)
				else
				(
					addModifier sel normalMod
					
					case meshType.state  of
					(
						1 : (
							convertToPoly sel
						)
						2 : (
							convertToMesh sel
						)
						3 : ()
					)
				)
			)--END undo
		)--END process.pressed
	)--End RO
	createdialog flipFlop
)

Anubis · 2010-03-10

Why don't you just apply a normal modifier as instance to all selected objects?